The delicious add-on for Firefox lets us select some text on a web page and click on a button to add the page to your online bookmarks at delicious.com. The selected text will then be auto populated in the NOTES field of the bookmarking form. We can achieve a similar functionality in Chrome (or for that matter, any browser with little tweaking).

This post is about a AutoHotKey script using which you can select text on a web page, press a customizable hotkey and submit the page to delicious with NOTES field pre-filled automatically. All you need to do is enter/select the tags and hit Return to submit the form.

Here are the steps:

1. Download and install AutoHotKey if you don’t have it already present on your computer.
2. Download this (for XP) or this (for Vista) small ChromeToDelicious.ahk file (the contained code can be found at the end of this post) and double click on it. You should see a H shaped icon in the system tray. Keep it running.
3. Log into your account at delicious.com.

That’s it!

Now whenever you want to bookmark a page (Example: http://chromespot.com/) to your delicious, highlight some relevant text on the page

and press one of the default hotkeys Ctrl+Shift+B or Ctrl+Shift+D (you can change these by editing the script and reloading it) and a window pop up like this will appear:

The code:

; ^ = Ctrl, ! = Alt, + = Shift, # = Win
; Relevant blog post: http://www.howtotuts.com/2008/09/08/how-to-accelerate-bookmarking-to-delicious-from-chrome/
; Author: Sridhar Katakam (http://www.howtotuts.com/)
; Thanks to: Suresh Kumar (http://www.autohotkey.com/forum/profile.php?mode=viewprofile&u=1820)

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance force
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.

#IfWinActive ahk_class Chrome_XPFrame

; Bookmarking in delicious start
~^+b:: ;Ctrl+Shift+b ('b' for bookmarking)
~^+d:: ; or Ctrl+Shift+d ('d' for delicious)

clipboard = ;Empty clipboard
Send, ^c ;Copy current selected text. Make sure text is selected by dragging the text with mouse and not by double clicking
ClipWait ;Wait for the clipboard to contain text
Notes := clipboard ;Store current selected text in a variable called 'Notes'
clipboard= ;Empty clipboard
clipboard = javascript:(function(){f='http://delicious.com/save?url='+encodeURIComponent(window.location.href)+'&title='+encodeURIComponent(document.title)+'&v=5&';a=function(){if(!window.open(f+'noui=1&jump=doclose','deliciousuiv5','location=yes,links=no,scrollbars=no,toolbar=no,width=550,height=550'))location.href=f+'jump=yes'};if(/Firefox/.test(navigator.userAgent)){setTimeout(a,0)}else{a()}})() ;Delicious bookmarklet code
ClipWait, 2 ;Set max seconds to wait for until clipboard contains data to 2
Send, !d ;Focus address bar
Sleep, 500 ;Pause half a second
Send, ^v{Enter} ;Paste delicious bookmarking URL and press enter
WinWait, Save a Bookmark on Delicious ;Wait till the bookmarking window appears
WinMove, Save a Bookmark on Delicious, ,(A_ScreenWidth/2)-(275),(A_ScreenHeight/2)-(275) ;Center the bookmarking window
Sleep, 4000 ;Pauses 4 seconds
Send, +{Tab} ;Press Shift+Tab so that the cursor is taken to Notes field
Sleep, 50 ;A short pause
Send %Notes% ;Type the earlier selected text
Sleep, 500 ;Pause half a second
Send {Tab} ;Move to Tags field
clipboard = ;Empty the clipboard
Return ;Done
; Bookmarking in delicious end

#IfWinActive

Note: There will be a visible delay before NOTES field gets populated with the text that you selected on the page. This is to accommodate varying net connection speeds. If you feel that you are waiting a couple extra seconds, adjust the pause seconds in the script.

Related posts:

1. How to post to Twitter from Chrome
2. How to search in google from any windows application easily
3. How to set keyboard shortcuts in Chrome

Related posts brought to you by Yet Another Related Posts Plugin.